Tutorial Arduino III. Sensores DHT y Display LCD

En este tutorial de Arduino vamos a medir la temperatura ambiente y el nivel de humedad relativa con un sensor digital de la familia DHT, en concreto el DHT22, y mostrarla en un display LCD de 16x2, de esta forma podemos familiarizarnos con el manejo de sensores digitales. El tutorial es válido para cualquier sensor de esta familia. Las ventajas de estos frente a los analógicos son dos: por un lado el nivel de precisión y rango de medida son superiores en los digitales (dejando a parte los termopares), además los sensores analógicos al enviar una lectura en forma de voltaje, no deben utilizarse con largas tiradas de cable, sino que deben estar físicamente cerca de la placa que recibe la lectura para evitar perdidas, lo que limita sus aplicaciones practicas. Este inconveniente no se da en los sensores digitales, por razones obvias.

La familia de sensores ambientales DHT esta formada por tres modelos: DHT11, DHT21 y DHT22, estos dos últimos se presentan en dos versiones diferentes, la básica, para soldar o pinchar directamente en protoboard y la encapsulada y cableada, mucho más práctica que es la podéis encontrar en nuestra tienda.

Las características generales de estos sensores son (el DHT22 es una evolución del DHT21 con unas prestaciones muy similares):

La estructura para la conexión de estos sensores es la misma en todos los modelos, un pin para la alimentación, otro para el GND y otro para datos. El cuarto pin es para la función "disconected" que rara vez se utiliza, de hecho en las versiones encapsuladas (como la que vamos a usar) si bien el pin esta presente no esta cableado, por lo que solo habrá tres cables: el rojo (alimentación), negro (GND) y amarillo (datos).

Material Necesario

El material necesario para la realización de este tutorial consiste en:

1. Arduino Uno
2. Breadboard con Puentes de Conexion
3. Sensor de Temperatura DHT22
4. Display LCD 16x2 LMB162HBC
5. Resistencia variable de 10K Ohm
6. Resistencia 1/4w 10K Ohm
7. Tira de 40 Pines Macho

Esquema de Montaje

Los datasheet del sensor DHT22 y del Display LCD son:

1. Datasheet Sensor DHT22
2. Datasheet Display LCD LMB162HBC

El esquema de montaje en Fritzing de todos los componentes y las conexiones necesarias es el siguiente:

En lo que se refiere al conexionado del Display LCD es el mismo que usamos en el anterior Tutorial Arduino: Sensor TMP36 y Display LCD, que repetimos:

• Salida 5V del Arduino al positivo de la Breadboard 
• GND del Arduino al GND de la Breadboard 
• Un pin del potenciometro de 10K Ohm al positivo de la Breadboard 
• Pin central del potenciometro de 10K Ohm al GND de la Breadboard 
• El tercer pin del potenciometro de 10K Ohm al pin 3 del LCD (V0) 
• Pin 15 LCD  (BLA) al positivo de la breadboard  
• Pin 16 LCD (BLK) al GND de la breadboard  
• Pin 1 LCD (VSS) al GND de la Breadboard  
• Pin 2 LCD  (VDD) al positivo de la Breadboard
• Pin 4 LCD (RS) a la salida 7 del Arduino  
• Pin 5 LCD (R/W) al GND de la Breadboard 
• Pin 6 LCD (E) a la salida 8 del Arduino 
• Pin 11 LCD (DB4) a la salida 9 del Arduino 
• Pin 12 LCD (DB5) a la salida 10 del Arduino 
• Pin 13 LCD (DB6) a la salida 11 del Arduino 
• Pin 14 LCD (DB7) a la salida 12 del Arduino 

La resistencia variable de 10K Ohm se utiliza para regular el contraste del display LCD por lo que para ver los datos que enviemos al mismo hay que ajustarlo manualmente mediante un eje o un pequeño destornillador.

En lo que respecta al sensor DHT22, en nuestra versión encapsulada y cableada, tenemos tres cables, el rojo para la alimentación, el negro para el GND y el amarillo para datos conectado en nuestro ejemplo al pin 2 de Arduino. La única particularidad es que montamos una resistencia "pull-up" de 10K Ohm que conecta el voltaje con el pin de datos.

Sketch Arduino

Para el uso de este sensor, como en otros muchos casos, es necesario instalar de forma previa la librería correspondiente, sino se esta familiarizado con este proceso resultar interesante leer nuestro Tutorial Arduino II: Librerias Arduino.

Podéis descargar la librería necesaria aquí: Librería Sensores DHT.

El sketch para mostrar los datos de temperatura y humedad relativa en el display LCD es:

#include <LiquidCrystal.h> 
//Llamamos a la libreria para controlar el LCD incluida en el IDE de Arduino
LiquidCrystal lcd(7, 8, 9, 10, 11 , 12); 
//Definimos los pines asignados al LCD según el esquema de conexión
#include "DHT.h"
//Llamamos a la libreria de los sensores DHT instalada previamente
#define DHTPIN 2 
#define DHTTYPE DHT22
//Definimos el pin de Arduino al que conectamos el pin de datos del sensor e indicamos el tipo de sensor (DHT22)

DHT dht(DHTPIN, DHTTYPE);

void setup(){
  Serial.begin(9600);
  Serial.println("Prueba DHT22");
//Iniciamos la comunicacion Monitor Serial y editamos un texto descriptivo

  dht.begin();
//Iniciamos el sensor
  }

void loop(){
 delay(2000);
//Establecemos un retraso porque el DHT22 solo realiza una lectura cada 2 segundos

  float h = dht.readHumidity();
  float t = dht.readTemperature();
//Establecemos dos variables, una para la temperatura en ºC y otra para la humedad relativa en %

  if (isnan(h) || isnan(t)) {
    Serial.println("Error al Leer Sensor DHT¡");
    return;
//Con la funcion isnan controlamos que el valor recibido del sensor sea un número, sino dara error
  }
  
  Serial.print("Humedad: "); 
  Serial.print(h);
  Serial.print(" %\t");
  Serial.print("Temperatura: "); 
  Serial.print(t);
  Serial.println(" *C ");
//Mostramos la información obtenida (temperatura y humedad) en el Monitor Serial
//El \t es equivalente al tabulador (separa los datos)
//El Serial.prinln nos cambia de linea en la siguiente lectura recibida

  lcd.begin(16, 2); 
//Indicamos el LCD que usamos: 16 caracteres y 2 lineas
  lcd.setCursor(0,0); 
//Situamos el cursor en la posicion 0 de la primera linea
  lcd.write("Temperatura: "); 
  lcd.setCursor(12,0); 
  lcd.print(t);
  lcd.setCursor(14,0); 
  lcd.write((char)223);
//Editamos el simbolo de los grados º
  lcd.setCursor(15,0); 
  lcd.write("C");
  lcd.setCursor(0,1); 
  lcd.write("Humedad: "); 
  lcd.setCursor(9,1); 
  lcd.print(h);
  lcd.setCursor(14,1);
  lcd.write("%");

} 

Una cosa interesante, la librería instalada permite manejar dos variables adicionales que no hemos usado, por un lado la temperatura en grados Farenheit y por otro el Heat Index, que es un valor que pretende relacionar la temperatura y la humedad para dar la temperatura percibida, una especie de "sensación térmica", expresada en grados Farenheit. Se definirían de esta forma:

  float f = dht.readTemperature(true);
  float hi = dht.computeHeatIndex(f, h);